import("library/lib_ascent").

WaitForEngineStart().

CORE:PART:GETMODULE("kOSProcessor"):DOEVENT("Open Terminal").

set profile to 0.7.
set turn_start to 1000.
set target_orbit to 100000.

when altitude > 80000 then {
	ag1 on.
}

Ascent(target_orbit, turn_start, profile, 3).
wait 0.5.
clearScreen.
print "Warping 1 orbit...".
local warpTgt is eta:apoapsis.

warpTo(time:seconds + warpTgt).
wait warpTgt + 1.

print "Preparing for De-orbit...".
lock steering to retrograde.
wait 20.
print "De-orbit Burn...".
lock throttle to 1.
wait until periapsis <= -200000.
print "Preparing for re-entry...".
lock throttle to 0.
wait until throttle = 0.
wait 1.
stage.
wait 1.

set kuniverse:timewarp:rate to 10.
wait until altitude <= 80000.

print "Re-entry...".
lock steering to srfRetrograde.

wait until altitude <= 20000.

print "Falling to ground...".

unlock steering.
set kuniverse:timewarp:rate to 5.

wait until ship:status = "LANDED" or ship:status = "SPLASHED".
set kuniverse:timewarp:rate to 0.

print "Mssion Complete!".
SET V0 TO GETVOICE(0). 
V0:PLAY( NOTE(400, 2.5) ).

CORE:PART:GETMODULE("kOSProcessor"):DOEVENT("Close Terminal").
SHUTDOWN.