run "library/lib_math".
run "library/lib_vessel_utils".

local athmoAccelTarget is 600.

CORE:PART:GETMODULE("kOSProcessor"):DOEVENT("Open Terminal").

clearScreen.
BRAKES on.
print "Waiting for engine ignition".
WaitForEngineStart().

print "Preparing to launch".
from { local c is 5.} until c = 0 step {set c to c - 1.} do {
	print c.
	wait 1.
}
clearScreen.
print "Launching!".
// stage.
lock throttle to 1.
lock steering to heading(90, 1).
brakes off.
sas off.

print "Phase: Takeoff".

wait until groundspeed > 120.

print "Phase: Rotate".
lock steering to heading(90, 4).
wait until altitude > 80.
print "Gear up".
gear off.

print "Phase: Athmospheric Acceleration".
lock steering to heading(90, 3, 0).
wait until groundspeed > athmoAccelTarget.

print "Phase: Athmospheric Climb".
lock tgtPitch to Map(groundSpeed, athmoAccelTarget, 1600, 3, 15).
lock steering to heading(90, tgtPitch, 0).

wait until altitude > 25000.

print "Phase: Mode Switch".
ag1 on. //Switch engine mode
lock steering to heading(90, 25, 0).
wait until apoapsis > 80000.

print "Phase: Sub-Orbital Coast".
lock throttle to 0.
set warpmode to "physics".
set warp to 1.

wait until altitude > 70000.
print "Deploying Solar".
panels on. //deploy solar
print "Opening Docking Port".
ag3 on. //open docking port
lock steering to heading(90, 0, 0).
set warp to 0.
set warpmode to "rails".
set warp to 1.


lock distToApo to apoapsis - altitude.
wait until distToApo < 500.

print "Phase: Circularize".
lock steering to heading(90, 0, 0).
rcs on.
lock throttle to 1.
wait until periapsis > 75000.
unlock throttle.

print "In orbit. Releasing controls".