kOS/library/lib_vessel_utils.ks

declare function WaitForEngineStart{
	wait until AnyEngineActive().
}

declare function GetDrag{
	parameter localGravity.
	return ship:sensors:acc:mag + localGravity.
}

declare function GetDragDir{
	parameter localGravity.
	parameter dir.
	return vDot(ship:sensors:acc, dir) + localGravity.
}

declare function AnyEngineActive{
	list engines in egs.
	for eng in egs{
		if eng:ignition {
			return true.
		}
	}
	return false.
}

declare function GetIsp{
	LIST ENGINES IN egs.
	declare local totalThrust is ship:maxThrust.
	local sum is 0.
	local weights is 0.
	for eng in egs{
		if eng:IGNITION and not eng:flameout{
			local w is  eng:AVAILABLETHRUST / totalThrust.
			local ispW is eng:isp * w.
			set sum to sum + ispW.
			set weights to weights + w.
		}
	}
	return sum / weights.
}

declare function GetIspForStage{
	parameter engineStage.
	parameter pressure is 0.
	LIST ENGINES IN egs.
	local totalThrust is GetThrustOfStage(engineStage, pressure).
	if totalThrust = 0{
		return 0.
	}
	local sum is 0.
	local weights is 0.
	for eng in egs{
		if eng:stage = engineStage {
			local w is eng:POSSIBLETHRUSTAT(pressure) / totalThrust.
			local ispW is eng:ispat(pressure) * w.
			set sum to sum + ispW.
			set weights to weights + w.
		}
	}
	return sum / weights.
}

declare function GetMaxMassFlow{
	LIST ENGINES IN egs.
	local sum is 0.
	for eng in egs{
		if eng:IGNITION and not eng:flameout{
			set sum to sum + eng:maxmassflow.
		}
	}
	return sum.
}

declare function GetMaxMassFlowForStage{
	parameter engineStage.
	LIST ENGINES IN egs.
	local sum is 0.
	for eng in egs{
		if eng:stage = engineStage {
			set sum to sum + eng:maxmassflow.
		}
	}
	return sum.
}




declare function CalculateSuicideBurnDuration
{
	parameter isp.
	return CalculateBurnDuration(verticalSpeed, isp, ship:mass, GetMaxMassFlow() * 1000).
}

declare function CalculateBurnDuration
{
	parameter dv.
	parameter burnIsp.
	parameter initialMass.
	parameter massFlow.

	if burnIsp = 0 {
		return 0.
	}
	set dv to abs(dv).
	local exp is -dv / (burnIsp * constant:g0).
	local massRatio is constant:e ^ (-exp).
	local finalMass is initialMass / massRatio.
	local fuelUsed is initialMass - finalMass.

	if massFlow <= 0{
		return 0.
	}

	return fuelUsed / massFlow.
}


declare function CalculateSuicideBurnAltitude
{
	parameter vertSpeed.
	parameter localGravity.
	parameter tgtAltitude is 0.0.
	parameter drag is 0.0.

	local vertAcc is CalculateAverageDecceleration(localGravity, drag).
	local burnAltitude is ((vertSpeed^2) / (2 * (vertAcc))).
	return burnAltitude + tgtAltitude.
}



declare function CalculateAverageDecceleration{
	parameter localGravity.
	parameter drag is 0.
	local maxVertAcc is (ship:availablethrust / ship:mass) - localGravity.

	return maxVertAcc + drag.
}

declare function GetLocalGravity{
	parameter curAltitude is -1.
	
	if curAltitude = -1 {
		set curAltitude to altitude.
	}
	return body:mu / (curAltitude + body:radius)^2.
}

declare function CalculateTimeToImpact{
	parameter vertSpeed.
	parameter curAltitude.
	parameter gravity.
	parameter tgtAltitude is 0.0.

	if gravity <= 0 or curAltitude <= 0{
		print "[warn]: invalid altitude or gravity.".
		return 0.0.
	}

	local vs is abs(vertSpeed).
	local g is gravity.
	local hRel is curAltitude - tgtAltitude.
	local disc is ((vs^2) + (2 * g * hRel)).
	return (vs + sqrt(disc)) / g.
}

function CalculateMultiStageBurnDuration{
	parameter dv.
	if ship:STAGEDELTAV(ship:stagenum):current >= dv {
		return CalculateBurnDuration(dv, GetIsp(), ship:mass, GetMaxMassFlow()).
	}else{
		local burnTime is 0.
		local remDv is dv.
		from {local s is ship:stagenum. } until s = -1 step { set s to s-1.} do {
			if remDv <= 0 {
				return burnTime.
			}
			local cdv is ship:stagedeltav(s):current.
			local cmass is GetMassOfStage(s).
			local cflow is GetMaxMassFlowForStage(s).
			local cisp is GetIspForStage(s).
			local sdv is 0.
			print cdv.
			if cdv >= remDv {
				set sdv to remDv.
			}else{
				set sdv to cdv.
			}
			set burnTime to burnTime + CalculateBurnDuration(sdv, cisp, cmass, cflow).
			set remDv to remDv - cdv.
		}
		return burnTime.
	}
}


function GetThrustOfStage {
	parameter st.
	parameter pressure is 0.

	local totalThrust is 0.
	LIST ENGINES IN egs.
	for eng in egs{
		if eng:stage = st {
			set totalThrust to totalThrust + eng:POSSIBLETHRUSTAT(pressure).
		}
	}
	return totalThrust.
}

function GetMassOfStage {
	parameter st.

	local total is 0.
	LIST PARTS IN allP.
	for p in allP {
		if p:stage <= st and p:DECOUPLEDIN < st {
			set total to total + p:mass.
		}
	}
	return total.
}